GroupBox.qml

Go to the documentation of this file.

// SPDX-FileCopyrightText: 2026 Pier Luigi Fiorini <pierluigi.fiorini@gmail.com>
// SPDX-License-Identifier: MPL-2.0
 
import QtQuick
import QtQuick.Templates as T
import Fluid as MD
 
T.GroupBox {
    id: control
 
    Accessible.role: Accessible.Grouping
    Accessible.name: title
 
    property MD.typescale typescale: MD.Tokens.typescale.labelMedium
 
    property real radius: MD.Tokens.shape.cornerValueMedium
 
    property bool outlineVisible: true
 
    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset, implicitContentWidth + leftPadding + rightPadding, implicitLabelWidth + leftPadding + rightPadding)
    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset, implicitContentHeight + topPadding + bottomPadding)
 
    spacing: MD.Tokens.measurement.space75
    padding: MD.Tokens.measurement.space150
    topPadding: padding + (implicitLabelWidth > 0 ? implicitLabelHeight : 0)
 
    label: MD.Label {
        objectName: "groupBoxLabel"
 
        x: Math.max(control.leftPadding, MD.Tokens.measurement.space50)
 
        width: control.availableWidth
 
        typescale: control.typescale
        text: control.title
        elide: Text.ElideRight
        verticalAlignment: Text.AlignVCenter
        Accessible.ignored: true
    }
 
    background: Rectangle {
        objectName: "groupBoxBackground"
 
        y: control.topPadding - control.bottomPadding
 
        width: parent.width
        height: parent.height - control.topPadding + control.bottomPadding
 
        color: "transparent"
        radius: control.radius
        border.width: control.outlineVisible ? 1 : 0
        border.color: control.MD.Style.outlineVariantColor
    }
}