PlainToolTip.qml

Go to the documentation of this file.

// SPDX-FileCopyrightText: 2026 Pier Luigi Fiorini <pierluigi.fiorini@gmail.com>
// SPDX-License-Identifier: MPL-2.0
 
pragma ComponentBehavior: Bound
 
import Fluid as MD
import "../core/UiMetrics.js" as UiMetrics
import "../internal/MotionAnimation.js" as MotionAnimation
 
import QtQuick
import QtQuick.Templates as T
 
T.ToolTip {
    id: control
    objectName: "plainToolTip"
 
    MD.Style.theme: control.parent ? control.parent.MD.Style.theme : MD.Style.System
 
    readonly property real _anchorWindowY: control.parent
                                           ? control.parent.mapToItem(null, 0, 0).y
                                             + control.parent.y * 0 : 0
    readonly property bool _opensBelow: control.parent
                                        ? control._anchorWindowY - control.height
                                          - MD.Tokens.toolTip.anchorSpacing
                                          < MD.Tokens.toolTip.viewportMargin : false
    readonly property bool _layoutMirrored: control.mirrored
                                            || control.locale.textDirection === Qt.RightToLeft
                                            || (control.parent
                                                && control.parent.LayoutMirroring.enabled)
    readonly property real _naturalWidth: control.implicitContentWidth
                                          + control.leftPadding + control.rightPadding
 
    x: control.parent ? (control.parent.width - control.width) / 2 : 0
    y: control.parent ? (control._opensBelow
                         ? control.parent.height + MD.Tokens.toolTip.anchorSpacing
                         : -control.height - MD.Tokens.toolTip.anchorSpacing) : 0
 
    implicitWidth: Math.max(MD.Tokens.toolTip.minimumWidth,
                            Math.min(MD.Tokens.toolTip.plainMaximumWidth, _naturalWidth))
    implicitHeight: Math.max(MD.Tokens.toolTip.minimumHeight,
                             control.implicitContentHeight
                             + control.topPadding + control.bottomPadding)
 
    margins: MD.Tokens.toolTip.viewportMargin
    leftPadding: MD.Tokens.toolTip.plainHorizontalPadding
    rightPadding: MD.Tokens.toolTip.plainHorizontalPadding
    topPadding: MD.Tokens.toolTip.plainVerticalPadding
    bottomPadding: MD.Tokens.toolTip.plainVerticalPadding
    closePolicy: T.Popup.CloseOnEscape | T.Popup.CloseOnPressOutsideParent
                 | T.Popup.CloseOnReleaseOutsideParent
    transformOrigin: control._opensBelow ? Item.Top : Item.Bottom
 
    contentItem: MD.Label {
        objectName: "plainToolTipLabel"
        width: control.availableWidth
        text: control.text
        typescale: MD.Tokens.typescale.bodySmall
        color: control.MD.Style.inverseOnSurfaceColor
        horizontalAlignment: control._layoutMirrored ? Text.AlignRight : Text.AlignLeft
        wrapMode: Text.Wrap
        elide: Text.ElideNone
        Accessible.ignored: true
    }
 
    background: Rectangle {
        objectName: "plainToolTipBackground"
        readonly property var containerShape: MD.Tokens.toolTip.plainContainerShape
 
        implicitWidth: MD.Tokens.toolTip.minimumWidth
        implicitHeight: MD.Tokens.toolTip.minimumHeight
        color: control.MD.Style.inverseSurfaceColor
        topLeftRadius: UiMetrics.resolveShapeRadius(containerShape.topLeft, width, height)
        topRightRadius: UiMetrics.resolveShapeRadius(containerShape.topRight, width, height)
        bottomLeftRadius: UiMetrics.resolveShapeRadius(containerShape.bottomLeft, width, height)
        bottomRightRadius: UiMetrics.resolveShapeRadius(containerShape.bottomRight, width, height)
    }
 
    enter: Transition {
        NumberAnimation {
            property: "scale"
            from: MD.Tokens.toolTip.closedScale
            to: 1
            duration: MotionAnimation.expressiveFastSpatialDuration
            easing.type: Easing.BezierSpline
            easing.bezierCurve: MotionAnimation.expressiveFastSpatialCurve
        }
        NumberAnimation {
            property: "opacity"
            from: 0
            to: 1
            duration: MotionAnimation.expressiveFastEffectsDuration
            easing.type: Easing.BezierSpline
            easing.bezierCurve: MotionAnimation.expressiveFastEffectsCurve
        }
    }
 
    exit: Transition {
        NumberAnimation {
            property: "scale"
            from: 1
            to: MD.Tokens.toolTip.closedScale
            duration: MotionAnimation.expressiveFastSpatialDuration
            easing.type: Easing.BezierSpline
            easing.bezierCurve: MotionAnimation.expressiveFastSpatialCurve
        }
        NumberAnimation {
            property: "opacity"
            from: 1
            to: 0
            duration: MotionAnimation.expressiveFastEffectsDuration
            easing.type: Easing.BezierSpline
            easing.bezierCurve: MotionAnimation.expressiveFastEffectsCurve
        }
    }
}