Wave.qml

Go to the documentation of this file.

// SPDX-FileCopyrightText: 2018 Michael Spencer <sonrisesoftware@gmail.com>
// SPDX-FileCopyrightText: 2014 Bogdan Cuza <bogdan.cuza@hotmail.com>
// SPDX-License-Identifier: MPL-2.0
 
pragma ComponentBehavior: Bound
 
import QtQuick
import QtQuick.Effects
 
Item {
    id: wave
    Accessible.ignored: true
 
    property bool open: false
 
    property real size: 0
 
    property real initialX
 
    property real initialY
 
    property real abstractWidth: parent.width
 
    property real abstractHeight: parent.height
 
    property real diameter: 2 * Math.sqrt(Math.pow(Math.max(initialX, abstractWidth - initialX), 2) + Math.pow(Math.max(initialY, abstractHeight - initialY), 2))
 
    signal finished(bool open)
 
    function openWave(x, y) {
        wave.initialX = x || parent.width / 2;
        wave.initialY = y || parent.height / 2;
        wave.open = true;
    }
 
    function closeWave(x, y) {
        wave.initialX = x || parent.width / 2;
        wave.initialY = y || parent.height / 2;
        wave.open = false;
    }
 
    visible: open
    layer.enabled: true
    layer.effect: MultiEffect {
        maskEnabled: true
        maskSource: ShaderEffectSource {
            sourceItem: Item {
                width: wave.width
                height: wave.height
                Rectangle {
                    x: wave.initialX - wave.size / 2
                    y: wave.initialY - wave.size / 2
                    width: wave.size
                    height: wave.size
                    radius: wave.size / 2
                }
            }
        }
    }
 
    states: State {
        name: "open"
        when: wave.open
 
        PropertyChanges {
            wave.size: wave.diameter
        }
    }
 
    transitions: Transition {
        from: ""
        to: "open"
        reversible: true
 
        SequentialAnimation {
            ScriptAction {
                script: wave.visible = wave.open
            }
            NumberAnimation {
                property: "size"
                easing.type: Easing.OutCubic
            }
            ScriptAction {
                script: wave.finished(wave.open)
            }
        }
    }
}