Breakpoints.qml

Go to the documentation of this file.

// SPDX-FileCopyrightText: 2026 Pier Luigi Fiorini <pierluigi.fiorini@gmail.com>
// SPDX-License-Identifier: MPL-2.0
 
pragma Singleton
 
import QtQuick
import Fluid as MD
 
QtObject {
    enum Breakpoint {
        Compact,
        Medium,
        Expanded,
        Large,
        ExtraLarge
    }
 
    readonly property real compactLowerBound: 0
 
    readonly property real mediumLowerBound: 600
 
    readonly property real expandedLowerBound: 840
 
    readonly property real largeLowerBound: 1200
 
    readonly property real extraLargeLowerBound: 1600
 
    function fromWidth(width) {
        if (typeof width !== "number" || !Number.isFinite(width) || width < compactLowerBound)
            return Breakpoints.Compact;
        if (width >= extraLargeLowerBound)
            return Breakpoints.ExtraLarge;
        if (width >= largeLowerBound)
            return Breakpoints.Large;
        if (width >= expandedLowerBound)
            return Breakpoints.Expanded;
        if (width >= mediumLowerBound)
            return Breakpoints.Medium;
        return Breakpoints.Compact;
    }
 
    function columnCount(breakpoint) {
        switch (breakpoint) {
        case Breakpoints.Medium:
        case Breakpoints.Expanded:
            return 8;
        case Breakpoints.Large:
        case Breakpoints.ExtraLarge:
            return 12;
        case Breakpoints.Compact:
        default:
            return 4;
        }
    }
 
    function margin(breakpoint) {
        switch (breakpoint) {
        case Breakpoints.Medium:
        case Breakpoints.Expanded:
        case Breakpoints.Large:
        case Breakpoints.ExtraLarge:
            return MD.Tokens.measurement.space300;
        case Breakpoints.Compact:
        default:
            return MD.Tokens.measurement.space200;
        }
    }
 
    function gutter(breakpoint) {
        switch (breakpoint) {
        case Breakpoints.Medium:
        case Breakpoints.Expanded:
        case Breakpoints.Large:
        case Breakpoints.ExtraLarge:
            return MD.Tokens.measurement.space300;
        case Breakpoints.Compact:
        default:
            return MD.Tokens.measurement.space200;
        }
    }
}